home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / pc / LOGIC Apple II 5.25" Library - DOS Part 3 / DOS066.dsk / FOOD VALUES.bas < prev    next >
BASIC Source File  |  2012-02-16  |  9KB  |  207 lines
  1. 100  REM   --> FOOD GRAPH.  CURT TORGERSON
  2. 110  REM   --> DATA FROM NATIONAL DAIRY COUNCIL
  3. 120  REM  
  4. 130  REM   --> ASSIGNMENTS
  5. 140  TEXT : HOME :D$ =  CHR$(4):LF$ =  CHR$(10)
  6. 150 N1 = 62:BADSP = 70: SPEED= 255
  7. 160  FOR K = 0 TO 23
  8. 170  READ NTE: POKE 944 +K,NTE
  9. 180  NEXT K
  10. 190  REM  
  11. 200  REM   --> INFORMATION ON PROGRAM
  12. 210  VTAB 8: INPUT "INFORMATION ON 'FOOD GRAPHS' (Y,N)? ";I$
  13. 220  IF I$ < >"Y"  THEN 660
  14. 230  HOME : PRINT LF$;" ENTER THE NAME OF A COMMON FOOD,"
  15. 240  PRINT LF$;"(SPELLED CORRECTLY!) AND THIS PROGRAM"
  16. 250  PRINT LF$;"WILL SEARCH FOR IT. IF THE FOOD IS"
  17. 260  PRINT LF$;"FOUND, A GRAPH ILLUSTRATING THE"
  18. 270  PRINT LF$;"CONTRIBUTION OF THAT FOOD TO U. S."
  19. 280  PRINT LF$;"RECOMMENDED DAILY ALLOWANCES WILL BE"
  20. 290  PRINT LF$;"PRINTED ON THE TV SCREEN IN COLOR."
  21. 300  GOSUB 1100
  22. 310  PRINT LF$;" NOTE THAT THE RECOMMENDED DAILY"
  23. 320  PRINT LF$;"ALLOWANCES CHANGE SOMEWHAT DEPENDING"
  24. 330  PRINT LF$;"ON WHETHER THE USER IS MALE, FEMALE,"
  25. 340  PRINT LF$;"UNDER 11 YEARS, UNDER 15 YEARS OR"
  26. 350  PRINT LF$;"UNDER 18 YEARS OF AGE"
  27. 360  PRINT LF$;" ALSO, THE GRAPH'S UPPER LIMIT IS 39%"
  28. 370  PRINT LF$;"AND SOME FOODS MAY SUPPLY MORE THAN"
  29. 380  PRINT LF$;"THAT PERCENTAGE OF NUTRITIVE VALUE."
  30. 390  GOSUB 1100
  31. 400  PRINT LF$;" TYPING 'STOP' AFTER A QUESTION MARK"
  32. 410  PRINT LF$;"WILL STOP THE PROGRAM FOR YOU."
  33. 420  PRINT LF$;" TYPE 'HELP' AFTER A QUESTION MARK TO"
  34. 430  PRINT LF$;"GET A LIST OF ABBREVIATIONS AND THEIR"
  35. 440  PRINT LF$;"MEANINGS, AND ALSO THE FOOD LIST."
  36. 450  PRINT LF$;" IF THE FOOD YOU ASK FOR IS NOT ON THE"
  37. 460  PRINT LF$;"PROGRAM'S LIST, IT WILL TELL YOU AND"
  38. 470  PRINT LF$;"YOU MAY STOP OR ASK FOR ANOTHER FOOD."
  39. 480  PRINT LF$;" AFTER THE GRAPH HAS BEEN PRINTED FOR"
  40. 490  PRINT LF$;"YOU, PRESS 'SPACE BAR' TO GET ANOTHER,"
  41. 500  PRINT LF$;"GRAPH."
  42. 510  GOSUB 1100: GOSUB 540: GOSUB 1100
  43. 520  GOTO 660
  44. 530  REM   --> FOOD INFO SUBROUTINE
  45. 540  PRINT LF$;" ON THE LEFT OF THE SCREEN WILL BE 7"
  46. 550  PRINT LF$;"WHITE BLOCKS, REPRESENTING THE 5%, 10%"
  47. 560  PRINT LF$;"15%, 20%, 25%, 30% AND 35% U. S."
  48. 570  PRINT LF$;"RECOMMENDED DAILY ALLOWANCES."
  49. 580  PRINT LF$;" THE ABBREVIATIONS BELOW THE BAR GRAPH"
  50. 590  PRINT LF$;"ARE 'CAL'=CALORIES, 'PRO'=PROTEIN,"
  51. 600  PRINT LF$;"'V-A'=VITAMIN A, 'V-C'=VITAMIN C,"
  52. 610  PRINT LF$;"'THI'=THIAMIN, 'RIB'=RIBOFLAVIN,"
  53. 620  PRINT LF$;"'NIA'=NIACIN, 'CALC'=CALCIUM, AND"
  54. 630  PRINT LF$;"'IR'=IRON"
  55. 640  RETURN 
  56. 650  REM   -->READ BLOCK OF FOOD DATA
  57. 660  DIM FOOD$(N1),PRTN$(N1),X(N1,9)
  58. 670  POKE 944,183: CALL 946
  59. 680  VTAB 12: HTAB 4: PRINT "FOOD RECORDS READ"
  60. 690  FOR K = 1 TO N1
  61. 700  READ FOOD$(K),PRTN$(K),X(K,1),X(K,2),X(K,3),X(K,4),X(K,5),X(K,6),X(K,7),X(K,8),X(K,9)
  62. 710  VTAB 12: PRINT K
  63. 720  NEXT K: POKE 944,220: CALL 946
  64. 730  GOSUB 760: GOTO 840
  65. 740  REM  
  66. 750  REM   --> FOOD LIST SUBROUTINE
  67. 760  HOME : VTAB 3: PRINT " HERE ARE THE FOODS ON THE LIST.";LF$
  68. 770  FOR J = 1 TO N1  STEP 2
  69. 780  PRINT FOOD$(J); TAB( 22);FOOD$(J +1)
  70. 790  IF J < >29  THEN 810
  71. 800  GOSUB 1100: VTAB 5
  72. 810  NEXT J: GOSUB 1100: RETURN 
  73. 820  REM  
  74. 830  REM   --> MAIN ROUTINE
  75. 840  HOME : VTAB 12: INPUT "TYPE FOOD NAME OR STOP: ";L$
  76. 850  IF L$ < >"HELP"  THEN 890
  77. 860  HOME : GOSUB 540: GOSUB 1100
  78. 870  GOSUB 760
  79. 880  VTAB 10: PRINT " NOW CHOOSE YOUR FOOD, AGAIN.": GOTO 840
  80. 890  IF L$ = "STOP"  THEN 1510
  81. 900  FOR K = 1 TO N1
  82. 910  IF L$ = FOOD$(K)  THEN 1150
  83. 920  NEXT K
  84. 930 BADSP = BADSP +10
  85. 940  IF BADSP <205  THEN 970
  86. 950  HOME : VTAB 12: HTAB 12: PRINT "***SPELLING ERRORS***"
  87. 960  VTAB 14: HTAB 15: PRINT "***PROGRAM ENDS***": GOTO 2100
  88. 970  POKE 944,BADSP
  89. 980  CALL 946: VTAB 14
  90. 990  PRINT " --> SORRY, ";L$;" NOT ON LIST <--"
  91. 1000  VTAB 16: PRINT "PRESS RETURN."
  92. 1010  GET A$: HOME : GOTO 840
  93. 1020  NEXT K
  94. 1030  GOSUB 1300
  95. 1040  VTAB 12: INPUT " TYPE STOP OR ANOTHER FOOD: ";FOOD$
  96. 1050  IF FOOD$ = "STOP"  THEN 1490
  97. 1060  GOTO 840
  98. 1070  REM   --> END OF MAIN ROUTINE
  99. 1080  REM  
  100. 1090  REM   --> PAGE SUBROUTINE
  101. 1100  VTAB 23: HTAB 15: PRINT "PRESS 'SPACE BAR' TO GO ON."
  102. 1110  GET A$: HOME : RETURN 
  103. 1120  REM  
  104. 1130  REM  
  105. 1140  REM   --> CALL GRAPHICS, STOP, RETURN
  106. 1150  GOSUB 1270
  107. 1160  VTAB 8: HTAB 5: PRINT "REMEMBER......"
  108. 1170  VTAB 9: HTAB 10: PRINT "STOP WILL END PROGRAM."
  109. 1180  VTAB 10: HTAB 10: PRINT "HELP GIVES ABBREVS. AND FOODS"
  110. 1190  VTAB 12: INPUT "ANOTHER FOOD GRAPH (Y,N)? ";A$:A$ =  LEFT$(A$,1)
  111. 1200  IF A$ = "Y"  THEN 840
  112. 1210  IF A$ = "N"  THEN 2110
  113. 1220  POKE 944,20: CALL 946: POKE 944,22: CALL 946
  114. 1230  HOME : VTAB 12: PRINT "DO YOU MEAN YES OR NO??????"
  115. 1240  FOR K = 1 TO 800: NEXT K: HOME : GOTO 1190
  116. 1250  REM  
  117. 1260  REM   --> GRAPH SUBROUTINE
  118. 1270  GR 
  119. 1280  PRINT "     CAL PRO V-A V-C THI RIB NIA CALC IR"
  120. 1290  PRINT "% OF DAILY NEED. ";FOOD$(K);" ";PRTN$(K)
  121. 1300 P = 3
  122. 1310  COLOR= 10: FOR J = 5 TO 35  STEP 5
  123. 1320  VLIN 39 -J,39 -J +1 AT 1
  124. 1330  NEXT J
  125. 1340  FOR L = 1 TO 9
  126. 1350  COLOR= L
  127. 1360 P = P +4
  128. 1370  VLIN 39,39 -X(K,L) AT P
  129. 1380  NEXT L
  130. 1390  POKE 944,25: CALL 946
  131. 1400  GET A$: TEXT : HOME : RETURN 
  132. 1410  REM  
  133. 1420  REM   --> TONE GENERATOR DATA BLOCK
  134. 1430  DATA   255,255,173,48,192,136,208,5
  135. 1440  DATA   206,177,3,240,9,202,208,245
  136. 1450  DATA   174,176,3,76,178,3,96,0
  137. 1460  REM  
  138. 1470  REM   --> FOOD DATA BLOCK
  139. 1480  DATA   "CHEDDAR CHEESE","1 OZ",6,15,5,2,1,6,1,21,1
  140. 1490  DATA   "COTTAGE CHEESE","1/2 CUP",6,34,4,0,3,17,1,12,2
  141. 1500  DATA   "ICE CREAM","1/2 CUP",7,6,7,2,3,8,1,8,1
  142. 1510  DATA   MILK,"1 CUP",7,16,5,4,7,28,1,29,0
  143. 1520  DATA   "CHOCOLATE MILK","1 CUP",11,19,6,5,5,25,2,27,4
  144. 1530  DATA   "SKIM MILK","1 CUP",4,16,10,4,7,28,1,30,0
  145. 1540  DATA   YOGURT,"1 CUP",11,20,2,8,6,24,1,29,1
  146. 1550  DATA   "BEEF LIVER","3 OZ",10,39,39,38,16,39,39,1,39
  147. 1560  DATA   BACON,"2 SLICES",5,10,0,0,6,4,5,0,4
  148. 1570  DATA   "FRIED CHICKEN","3 OZ",10,39,3,0,4,23,30,1,12
  149. 1580  DATA   "FRANKFURTER","2 OZ",9,16,0,0,7,7,8,1,6
  150. 1590  DATA   "PEANUT BUTTER","2 TBSP",9,14,0,0,3,2,26,2,3
  151. 1600  DATA   "PORK CHOP","3 OZ",15,39,0,0,39,14,25,1,16
  152. 1610  DATA   "APPLE","MEDIUM SIZE",4,1,2,10,3,2,0,1,2
  153. 1620  DATA   "FRENCH FRIES","20 PIECES",12,6,0,30,7,5,13,1,6
  154. 1630  DATA   "BANANA","MEDIUM SIZE",5,2,5,20,4,4,4,1,4
  155. 1640  DATA   "GREEN BEANS","1/2 CUP",1,2,7,14,3,4,2,4,3
  156. 1650  DATA   CARROT,"5 IN.",1,1,39,7,2,2,1,2,2
  157. 1660  DATA   CORN,"1/2 CUP",4,3,67,6,2,3,5,1,3
  158. 1670  DATA   GRAPEFRUIT,"1/2 MEDIUM",2,1,10,39,3,2,2,3,4
  159. 1680  DATA   SPINACH,"1/2 CUP",0,3,39,39,5,7,2,10,8
  160. 1690  DATA   LETTUCE,"2 LEAVES",0,1,19,15,2,2,1,3,4
  161. 1700  DATA   "GREEN SALAD","3/4 CUP",1,1,27,39,2,2,1,3,3
  162. 1710  DATA   "ORANGE JUICE","1/2 CUP",3,1,5,39,7,0,2,1,0
  163. 1720  DATA   PEAS,"1/2 CUP",3,6,10,17,16,5,8,2,9
  164. 1730  DATA   "BAKED POTATO","5 OZ",6,5,0,39,8,4,13,1,7
  165. 1740  DATA   TOMATO,"3 SLICES",1,1,18,39,4,3,4,1,3
  166. 1750  DATA   "WHITE BREAD",SLICE,3,3,0,0,7,4,4,2,3
  167. 1760  DATA   "WHOLE WHEAT BREAD",SLICE,3,4,0,0,4,2,4,3,4
  168. 1770  DATA   "CORN FLAKES","3/4 CUP",4,2,0,0,6,1,2,0,2
  169. 1780  DATA   RICE,"1/2 CUP",6,3,0,0,7,5,6,1,5
  170. 1790  DATA   "HOT DOG","BUN AND WIENER",6,5,0,0,11,7,8,3,4
  171. 1800  DATA   HAMBURGER,"3 OZ",9,39,0,0,5,11,25,1,16
  172. 1810  DATA   "BAKED BEANS","1/2 CUP",8,12,3,5,7,2,4,7,14
  173. 1820  DATA   "MACRONI AND CHEESE","1/2 CUP",11,13,9,0,8,12,6,18,6
  174. 1830  DATA   PIZZA,"1/4 14' CHEESE PIE",18,18,19,20,25,28,19,33,16
  175. 1840  DATA   "CHOCOLATE BAR","1 OZ",7,3,2,0,2,7,1,8,2
  176. 1850  DATA   BUTTER,"1 TSP",2,0,4,0,0,0,0,0,0
  177. 1860  DATA   "CHOCOLATE CAKE","1/16 2'+ICIN",12,5,2,0,1,4,1,4,3
  178. 1870  DATA   "COFFEE,CREAM,SUGAR",CUP,2,1,1,0,1,1,3,2,1
  179. 1880  DATA   "SUGAR COOKIE","3 IN",4,2,0,0,3,2,2,2,2
  180. 1890  DATA   JELLO,"1/2 CUP",4,3,0,0,0,0,0,0,0
  181. 1900  DATA   WHISKEY,"1 OZ",5,0,0,0,0,0,0,0,0
  182. 1910  DATA   "APPLE PIE","1/6 SLICE",19,5,1,3,10,8,9,1,6
  183. 1920  DATA   POPCORN,"1 CUP PLAIN",1,1,0,0,0,1,1,0,1
  184. 1930  DATA   "POTATO CHIPS","10 2 IN",6,1,0,5,3,1,6,1,2
  185. 1940  DATA   COLA,"8 OZ",5,0,0,0,0,0,0,0,0
  186. 1950  DATA   DOUGHNUT,"1 PLAIN",6,2,1,0,5,4,3,1,2
  187. 1960  DATA   TUNA,"3 OZ",8,39,1,0,3,6,39,1,9
  188. 1970  DATA   TACO,"ONE BEEF",11,38,7,7,7,11,15,17,14
  189. 1980  DATA   BROCCOLI,"1/2 CUP",1,4,39,39,5,9,3,7,3
  190. 1990  DATA   PEANUTS,"1/4 CUP",11,14,0,0,8,3,31,3,4
  191. 2000  DATA   "ROAST BEEF","3 OZ",9,39,0,0,3,12,20,1,18
  192. 2010  DATA   "BAKED HAM","3 OZ",9,39,0,0,37,15,25,1,18
  193. 2020  DATA   BOLOGNA,"1 OZ",4,8,0,0,3,4,4,4,3
  194. 2030  DATA   WATERMELON,"1 CUP",3,1,24,23,4,4,2,1,6
  195. 2040  DATA   BAGEL,"ONE PLAIN",8,9,1,0,9,6,6,1,7
  196. 2050  DATA   "CHICKEN NOODLE SOUP","1 CUP",3,5,1,0,1,1,4,1,3
  197. 2060  DATA   "SPAGHETTI AND MEAT BALLS","1 CUP",17,29,32,37,17,18,20,12,21
  198. 2070  DATA   COLESLAW,"1/2 CUP",4,1,2,27,2,2,1,3,1
  199. 2080  DATA   STRAWBERRIES,"1/2 CUP",1,1,1,39,1,3,2,2,4
  200. 2090  DATA   PINEAPPLE,"LARGE SLICE",5,1,1,15,7,1,1,1,2
  201. 2100  FOR K = 1 TO 400: NEXT K
  202. 2110  POKE 944,95: CALL 946
  203. 2120  POKE 944,132: CALL 946
  204. 2130  POKE 944,126: CALL 946
  205. 2140  POKE 944,104: CALL 946
  206. 2150  HOME : VTAB 12: HTAB 18: PRINT "THE END"
  207. 2160  END